' SOMO demo program for picaxe 18A
'
' Attach a keyboard to the picaxe as per the documentation for KEYIN
'
' + Increases the volume
' - Decreases the volume
' Pause Pauses the sound
' Power Stops the sound
' 1 plays 4 files in sequence (see below)
' any other key plays the file with a name based upon its scan code
' eg a -> 0x28 -> 40 (dec) -> 0040.ad4
' b -> 0x32 -> 50 (dec) -> 0050.ad4
' 
' plays the file represented by the 
' 
' connect Output 0 (pin 6) to Somo sdata
' connect Output 1 (pin 7) to Somo sclk
' Connect Input 1 (pin 18) to Somo Busy
'
' Dummy simple exists to enable a short delay to be created
' 
'
symbol sdata = 0
symbol sclk = 1
symbol dummy = 2
symbol busy = 1
low sdata
high sclk
b0 = 7
main:
'get the keyboard hit
keyin 
if keyvalue = 121 and b0 < 7 then ' +
b0 = b0 + 1
lookup b0,($80,$81,$84,$85,$82,$83,$86,$87),b1
keyled b1
w6 = b0 + $fff0
gosub SendSOMO
else
if keyvalue = 123 and b0 > 0 then ' -
b0 = b0 - 1
lookup b0,($80,$81,$84,$85,$82,$83,$86,$87),b1
keyled b1
w6 = b0 + $fff0
gosub SendSOMO
else
if keyvalue = 225 then ' pause
w6 = $fffe
gosub SendSOMO
else
if keyvalue = 55 then ' stop
w6 = $ffff
gosub SendSOMO
else
if keyvalue = 22 then ' 1, a sequence
w6 = $ff
gosub SendSOMOWait
w6 = $fe
gosub SendSOMOWait
w6 = $fd
gosub SendSOMOWait
w6 = $fc
gosub SendSOMOWait
else ' play pressed key
w6 = keyvalue
gosub SendSOMO
endif
endif
endif
endif
endif
' debug b1
goto main
SendSOMOWait:
gosub sendsomo
swait:
pause 5
if pin1 = 1 then swait
pause 5
return
'
'
SendSOMO:
low sclk
pause 2
for b7 = 1 to 16 ' number of bits
w5 = w6 & $8000 ' mask MSB 
low sdata ' data low
if w5 = 0 then skipMSB 
high sdata ' data high

skipMSB:
pulsout dummy,100 ' 100us delay
pulsout sclk,200 ' pulse clock for 200us
w6 = w6 * 2 ' shift variable left for MSB 
pulsout dummy,100 ' 100us delay
next b7
high sclk
pause 2
return